Statistics
| Branch: | Revision:

iof-bird-daemon / configure.ac @ 7d5e61a6

History | View | Annotate | Download (11.3 KB)

1
dnl ** This is a configure script template for BIRD
2
dnl ** Process it with autoconf to get ./configure
3
dnl ** (c) 1999--2000 Martin Mares <mj@ucw.cz>
4

    
5
AC_INIT
6
AC_CONFIG_SRCDIR([conf/confbase.Y])
7
AC_CONFIG_AUX_DIR([tools])
8

    
9
AC_ARG_ENABLE([client],
10
  [AS_HELP_STRING([--enable-client], [enable building of BIRD client @<:@yes@:>@])],
11
  [],
12
  [enable_client=yes]
13
)
14

    
15
AC_ARG_ENABLE([debug],
16
  [AS_HELP_STRING([--enable-debug], [enable internal debugging routines @<:@no@:>@])],
17
  [],
18
  [enable_debug=no]
19
)
20

    
21
AC_ARG_ENABLE([memcheck],
22
  [AS_HELP_STRING([--enable-memcheck], [check memory allocations when debugging @<:@yes@:>@])],
23
  [],
24
  [enable_memcheck=yes]
25
)
26

    
27
AC_ARG_ENABLE([pthreads],
28
  [AS_HELP_STRING([--enable-pthreads], [enable POSIX threads support @<:@try@:>@])],
29
  [],
30
  [enable_pthreads=try]
31
)
32

    
33
AC_ARG_ENABLE([libssh],
34
  [AS_HELP_STRING([--enable-libssh], [enable LibSSH support together with RPKI @<:@try@:>@])],
35
  [],
36
  [enable_libssh=try]
37
)
38

    
39
AC_ARG_WITH([protocols],
40
  [AS_HELP_STRING([--with-protocols=LIST], [include specified routing protocols @<:@all@:>@])],
41
  [],
42
  [with_protocols="all"]
43
)
44

    
45
AC_ARG_WITH([sysconfig],
46
  [AS_HELP_STRING([--with-sysconfig=FILE], [use specified BIRD system configuration file])],
47
  []
48
)
49

    
50
AC_ARG_WITH([runtimedir],
51
  [AS_HELP_STRING([--with-runtimedir=PATH], [path for runtime files @<:@LOCALSTATEDIR/run@:>@])],
52
  [runtimedir="$with_runtimedir"],
53
  [runtimedir="\$(localstatedir)/run"]
54
)
55

    
56
AC_ARG_WITH([iproutedir],
57
  [AS_HELP_STRING([--with-iproutedir=PATH], [path to iproute2 config files @<:@/etc/iproute2@:>@])],
58
  [given_iproutedir="yes"]
59
)
60

    
61
AC_ARG_VAR([FLEX], [location of the Flex program])
62
AC_ARG_VAR([BISON], [location of the Bison program])
63
AC_ARG_VAR([M4], [location of the M4 program])
64

    
65

    
66
if test "$srcdir" = . ; then
67
  # Building in current directory => create obj directory holding all objects
68
  objdir=obj
69
else
70
  # Building in separate directory
71
  objdir=.
72
fi
73

    
74
exedir=.
75

    
76
AC_SUBST([objdir])
77
AC_SUBST([exedir])
78
AC_SUBST([srcdir])
79
AC_SUBST([runtimedir])
80

    
81

    
82
if test "$enable_debug" = yes ; then
83
  CONFIG_FILE="bird.conf"
84
  CONTROL_SOCKET="bird.ctl"
85
else
86
  CONFIG_FILE="\$(sysconfdir)/bird.conf"
87
  CONTROL_SOCKET="$runtimedir/bird.ctl"
88
fi
89
AC_SUBST([CONFIG_FILE])
90
AC_SUBST([CONTROL_SOCKET])
91

    
92
AC_SEARCH_LIBS([clock_gettime], [rt posix4],
93
  [],
94
  [AC_MSG_ERROR([Function clock_gettime not available.])]
95
)
96

    
97
AC_CANONICAL_HOST
98

    
99
# Store this value because ac_test_CFLAGS is overwritten by AC_PROG_CC
100
if test "$ac_test_CFLAGS" != set ; then
101
  bird_cflags_default=yes
102
fi
103

    
104
AC_PROG_CC
105
AC_PROG_CC_C99
106
if test -z "$GCC" ; then
107
  AC_MSG_ERROR([This program requires the GNU C Compiler.])
108
fi
109

    
110
if test "$enable_pthreads" != no ; then
111
  BIRD_CHECK_PTHREADS
112

    
113
  if test "$bird_cv_lib_pthreads" = yes ; then
114
    AC_DEFINE([USE_PTHREADS], [1], [Define to 1 if pthreads are enabled])
115
    CFLAGS="$CFLAGS -pthread"
116
    LDFLAGS="$LDFLAGS -pthread"
117
    proto_bfd=bfd
118
  elif test "$enable_pthreads" = yes ; then
119
    AC_MSG_ERROR([POSIX threads not available.])
120
  fi
121

    
122
  if test "$enable_pthreads" = try ; then
123
    enable_pthreads="$bird_cv_lib_pthreads"
124
  fi
125
fi
126

    
127
if test "$bird_cflags_default" = yes ; then
128
  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign], [-Wall])
129
  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers], [-Wall -Wextra])
130
  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
131
  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
132

    
133
  CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wno-parentheses"
134
  BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign])
135
  BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers])
136
  BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
137
  BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
138
fi
139
AC_MSG_CHECKING([CFLAGS])
140
AC_MSG_RESULT([$CFLAGS])
141

    
142

    
143
AC_PROG_CPP
144
AC_PROG_INSTALL
145
AC_PROG_RANLIB
146
AC_CHECK_PROG([FLEX], [flex], [flex])
147
AC_CHECK_PROG([BISON], [bison], [bison])
148
AC_CHECK_PROGS([M4], [gm4 m4])
149

    
150
test -z "$FLEX"	 && AC_MSG_ERROR([Flex is missing.])
151
test -z "$BISON" && AC_MSG_ERROR([Bison is missing.])
152
test -z "$M4"	 && AC_MSG_ERROR([M4 is missing.])
153

    
154
BIRD_CHECK_PROG_FLAVOR_GNU([$M4],
155
  [],
156
  [AC_MSG_ERROR([Provided M4 is not GNU M4.])]
157
)
158

    
159
if test -n "$with_sysconfig" -a "$with_sysconfig" != no ; then
160
  if test -f $with_sysconfig ; then
161
    sysdesc=$with_sysconfig
162
  else
163
    sysdesc=$srcdir/sysdep/cf/$with_sysconfig
164
    if ! test -f $sysdesc ; then
165
      sysdesc=$sysdesc.h
166
    fi
167
  fi
168
elif test -f sysconfig.h ; then
169
  sysdesc=sysconfig
170
else
171
  case "$host_os" in
172
    linux*)
173
      sysdesc=linux
174
      default_iproutedir="/etc/iproute2"
175
      ;;
176
    freebsd*)
177
      sysdesc=bsd
178
      ;;
179
    kfreebsd*)
180
      sysdesc=bsd
181
      ;;
182
    netbsd*)
183
      sysdesc=bsd
184
      CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
185
      LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
186
      ;;
187
    openbsd*)
188
      sysdesc=bsd
189
      ;;
190
    dragonfly*)
191
      sysdesc=bsd
192
      ;;
193
    *)
194
      AC_MSG_ERROR([Cannot determine correct system configuration. Please use --with-sysconfig to set it manually.])
195
      ;;
196
    esac
197
    sysdesc=$srcdir/sysdep/cf/$sysdesc.h
198
fi
199
AC_MSG_CHECKING([which OS configuration should we use])
200
AC_MSG_RESULT([$sysdesc])
201
if ! test -f $sysdesc ; then
202
  AC_MSG_ERROR([The system configuration file is missing.])
203
fi
204
sysname=`echo $sysdesc | sed 's/\.h$//'`
205
AC_DEFINE_UNQUOTED([SYSCONF_INCLUDE], ["$sysdesc"], [Which sysdep header to include])
206

    
207
AC_MSG_CHECKING([system-dependent directories])
208
sysdep_dirs="`sed <$sysdesc '/^Link: /!d;s/^Link: \(.*\)$/\1/' | tr '\012' ' '`"
209
AC_MSG_RESULT([$sysdep_dirs])
210
AC_SUBST([sysdep_dirs])
211

    
212
if test "$with_iproutedir" = no ; then with_iproutedir= ; fi
213

    
214
if test -n "$given_iproutedir"
215
then iproutedir=$with_iproutedir
216
else iproutedir=$default_iproutedir
217
fi
218

    
219
AC_SUBST([iproutedir])
220

    
221
DAEMON_LIBS=
222
AC_SUBST(DAEMON_LIBS)
223

    
224
if test "$enable_libssh" != no ; then
225
  AC_CHECK_HEADER([libssh/libssh.h], [true], [fail=yes], [ ])
226
  AC_CHECK_LIB([ssh], [ssh_connect], [true], [fail=yes])
227

    
228
  if test "$fail" != yes ; then
229
    AC_DEFINE([HAVE_LIBSSH], [1], [Define to 1 if you have the `ssh' library (-lssh).])
230
    DAEMON_LIBS="-lssh $DAEMON_LIBS"
231
    proto_rpki=rpki
232
    enable_libssh=yes
233
  else
234
    if test "$enable_libssh" = yes ; then
235
      AC_MSG_ERROR([LibSSH not available.])
236
    else
237
      enable_libssh=no
238
    fi
239
  fi
240
fi
241

    
242
all_protocols="$proto_bfd babel bgp ospf pipe radv rip $proto_rpki static"
243

    
244
all_protocols=`echo $all_protocols | sed 's/ /,/g'`
245

    
246
if test "$with_protocols" = all ; then
247
  with_protocols="$all_protocols"
248
fi
249

    
250
AH_TEMPLATE([CONFIG_BABEL], 	[Babel protocol])
251
AH_TEMPLATE([CONFIG_BFD],	[BFD protocol])
252
AH_TEMPLATE([CONFIG_BGP],	[BGP protocol])
253
AH_TEMPLATE([CONFIG_OSPF],	[OSPF protocol])
254
AH_TEMPLATE([CONFIG_PIPE],	[Pipe protocol])
255
AH_TEMPLATE([CONFIG_RADV],	[RAdv protocol])
256
AH_TEMPLATE([CONFIG_RIP],	[RIP protocol])
257
AH_TEMPLATE([CONFIG_RPKI],	[RPKI protocol])
258
AH_TEMPLATE([CONFIG_STATIC],	[Static protocol])
259

    
260
AC_MSG_CHECKING([protocols])
261
protocols=`echo "$with_protocols" | sed 's/,/ /g'`
262
if test "$protocols" = no ; then protocols= ; fi
263
for a in $protocols ; do
264
  if ! test -f $srcdir/proto/$a/Makefile ; then
265
    AC_MSG_RESULT([failed])
266
    AC_MSG_ERROR([Requested protocol $a not found])
267
  fi
268
  AC_DEFINE_UNQUOTED([CONFIG_`echo $a | tr 'a-z' 'A-Z'`])
269
done
270
AC_MSG_RESULT([ok])
271
AC_SUBST([protocols])
272

    
273
case $sysdesc in
274
  */linux*)
275
    AC_CHECK_HEADER([linux/rtnetlink.h],
276
      [],
277
      [AC_MSG_ERROR([Appropriate version of Linux kernel headers not found.])],
278
      [
279
	dnl Some older versions of Linux kernel headers require these includes
280
	#include <asm/types.h>
281
	#include <sys/socket.h>
282
      ]
283
    )
284
    ;;
285
esac
286

    
287
AC_CHECK_HEADERS_ONCE([alloca.h syslog.h])
288
AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [], [#include <sys/socket.h>])
289

    
290
AC_CHECK_HEADERS([linux/lwtunnel.h],
291
  [AC_DEFINE([HAVE_LWTUNNEL], [1], [Define to 1 if you have the <linux/lwtunnel.h> header file.])],
292
  [],
293
  [] dnl Force new AC_CHECK_HEADER semantics
294
)
295

    
296
AC_CHECK_MEMBERS([struct rtvia.rtvia_family],
297
  [AC_DEFINE([HAVE_STRUCT_RTVIA], [1], [Define to 1 if you have rtvia structure.])],
298
  [],
299
  [#include <linux/rtnetlink.h>]
300
)
301

    
302
AC_C_BIGENDIAN(
303
  [AC_DEFINE([CPU_BIG_ENDIAN], [1], [Define to 1 if cpu is big endian])],
304
  [AC_DEFINE([CPU_LITTLE_ENDIAN], [1], [Define to 1 if cpu is little endian])],
305
  [AC_MSG_ERROR([Cannot determine CPU endianity.])]
306
)
307

    
308
if test "$enable_debug" = yes ; then
309
  AC_DEFINE([DEBUGGING], [1], [Define to 1 if debugging is enabled])
310
  LDFLAGS="$LDFLAGS -rdynamic"
311
  CFLAGS="$CFLAGS -O0 -ggdb -g3 -gdwarf-4"
312

    
313
  AC_CHECK_HEADER([execinfo.h],
314
    [
315
      AC_DEFINE([HAVE_EXECINFO_H], [1], [Define to 1 if you have the <execinfo.h> header file.])
316
      AC_SEARCH_LIBS([backtrace], [execinfo],
317
	[]
318
	[AC_MSG_ERROR([Function backtrace not available.])]
319
      )
320
    ]
321
  )
322

    
323
  if test "$enable_memcheck" = yes ; then
324
    AC_CHECK_LIB([dmalloc], [dmalloc_debug])
325
    if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then
326
      AC_CHECK_LIB([efence], [malloc])
327
    fi
328
  fi
329
fi
330

    
331
CLIENT=birdcl
332
CLIENT_LIBS=
333
if test "$enable_client" = yes ; then
334
  CLIENT="$CLIENT birdc"
335
  BASE_LIBS="$LIBS"
336
  LIBS=""
337

    
338
  AC_CHECK_HEADERS([curses.h],
339
    [],
340
    [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
341
    [AC_INCLUDES_DEFAULT]
342
  )
343

    
344
  AC_SEARCH_LIBS([tgetent], [tinfo tinfow ncurses curses termcap],
345
    [TINFO_LIBS="$LIBS"; LIBS=""],
346
    [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
347
  )
348

    
349
  AC_CHECK_HEADERS([readline/readline.h readline/history.h],
350
    [],
351
    [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
352
    [AC_INCLUDES_DEFAULT]
353
  )
354

    
355
  AC_SEARCH_LIBS([rl_callback_read_char], [readline],
356
    [READLINE_LIBS="$LIBS"; LIBS=""],
357
    [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
358
    [$TINFO_LIBS]
359
  )
360

    
361
  AC_SEARCH_LIBS([add_history], [history readline],
362
    [HISTORY_LIBS="$LIBS"; LIBS=""],
363
    [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
364
    [$TINFO_LIBS]
365
  )
366

    
367
  AC_CHECK_LIB([readline], [rl_crlf],
368
    [AC_DEFINE([HAVE_RL_CRLF], [1], [Define to 1 if you have rl_crlf()])],
369
    [],
370
    [$TINFO_LIBS]
371
  )
372

    
373
  AC_CHECK_LIB([readline], [rl_ding],
374
    [AC_DEFINE([HAVE_RL_DING], [1], [Define to 1 if you have rl_ding()])],
375
    [],
376
    [$TINFO_LIBS]
377
  )
378

    
379
  LIBS="$BASE_LIBS"
380
  CLIENT_LIBS="$HISTORY_LIBS $READLINE_LIBS $TINFO_LIBS"
381
fi
382
AC_SUBST([CLIENT])
383
AC_SUBST([CLIENT_LIBS])
384

    
385
mkdir -p $objdir/sysdep
386
AC_CONFIG_HEADERS([$objdir/sysdep/autoconf.h:sysdep/autoconf.h.in])
387
AC_CONFIG_FILES([Makefile:Makefile.in])
388
AC_OUTPUT
389

    
390
AC_MSG_RESULT()
391
AC_MSG_RESULT([BIRD was configured with the following options:])
392
AC_MSG_RESULT([        Source directory:	$srcdir])
393
AC_MSG_RESULT([        Object directory:	$objdir])
394
AC_MSG_RESULT([        Iproute2 directory:	$iproutedir])
395
AC_MSG_RESULT([        System configuration:	$sysdesc])
396
AC_MSG_RESULT([        Debugging:		$enable_debug])
397
AC_MSG_RESULT([        POSIX threads:		$enable_pthreads])
398
AC_MSG_RESULT([        Routing protocols:	$protocols])
399
AC_MSG_RESULT([        Client:			$enable_client])
400

    
401
rm -f $objdir/.*-stamp