Statistics
| Branch: | Revision:

iof-bird / bird-2.0.1 / configure.ac @ 6b3f1a54

History | View | Annotate | Download (11.4 KB)

1
dnl ** This is a configure script template for BIRD
2
dnl ** Process it with autoconf to get ./configure
3
dnl ** (c) 1999--2000 Martin Mares <mj@ucw.cz>
4

    
5
AC_INIT
6
AC_CONFIG_SRCDIR([conf/confbase.Y])
7
AC_CONFIG_AUX_DIR([tools])
8

    
9
AC_ARG_ENABLE([client],
10
  [AS_HELP_STRING([--enable-client], [enable building of BIRD client @<:@yes@:>@])],
11
  [],
12
  [enable_client=yes]
13
)
14

    
15
AC_ARG_ENABLE([debug],
16
  [AS_HELP_STRING([--enable-debug], [enable internal debugging routines @<:@no@:>@])],
17
  [],
18
  [enable_debug=no]
19
)
20

    
21
AC_ARG_ENABLE([memcheck],
22
  [AS_HELP_STRING([--enable-memcheck], [check memory allocations when debugging @<:@yes@:>@])],
23
  [],
24
  [enable_memcheck=yes]
25
)
26

    
27
AC_ARG_ENABLE([pthreads],
28
  [AS_HELP_STRING([--enable-pthreads], [enable POSIX threads support @<:@try@:>@])],
29
  [],
30
  [enable_pthreads=try]
31
)
32

    
33
AC_ARG_ENABLE([libssh],
34
  [AS_HELP_STRING([--enable-libssh], [enable LibSSH support together with RPKI @<:@try@:>@])],
35
  [],
36
  [enable_libssh=try]
37
)
38

    
39
AC_ARG_ENABLE([mpls-kernel],
40
  [AS_HELP_STRING([--enable-mpls-kernel], [enable MPLS support in kernel protocol @<:@try@:>@])],
41
  [],
42
  [enable_mpls_kernel=try]
43
)
44

    
45
AC_ARG_WITH([protocols],
46
  [AS_HELP_STRING([--with-protocols=LIST], [include specified routing protocols @<:@all@:>@])],
47
  [],
48
  [with_protocols="all"]
49
)
50

    
51
AC_ARG_WITH([sysconfig],
52
  [AS_HELP_STRING([--with-sysconfig=FILE], [use specified BIRD system configuration file])],
53
  []
54
)
55

    
56
AC_ARG_WITH([runtimedir],
57
  [AS_HELP_STRING([--with-runtimedir=PATH], [path for runtime files @<:@LOCALSTATEDIR/run@:>@])],
58
  [runtimedir="$with_runtimedir"],
59
  [runtimedir="\$(localstatedir)/run"]
60
)
61

    
62
AC_ARG_WITH([iproutedir],
63
  [AS_HELP_STRING([--with-iproutedir=PATH], [path to iproute2 config files @<:@/etc/iproute2@:>@])],
64
  [given_iproutedir="yes"]
65
)
66

    
67
AC_ARG_VAR([FLEX], [location of the Flex program])
68
AC_ARG_VAR([BISON], [location of the Bison program])
69
AC_ARG_VAR([M4], [location of the M4 program])
70

    
71

    
72
if test "$srcdir" = . ; then
73
  # Building in current directory => create obj directory holding all objects
74
  objdir=obj
75
else
76
  # Building in separate directory
77
  objdir=.
78
fi
79

    
80
exedir=.
81

    
82
AC_SUBST([objdir])
83
AC_SUBST([exedir])
84
AC_SUBST([srcdir])
85
AC_SUBST([runtimedir])
86

    
87

    
88
if test "$enable_debug" = yes ; then
89
  CONFIG_FILE="bird.conf"
90
  CONTROL_SOCKET="bird.ctl"
91
else
92
  CONFIG_FILE="\$(sysconfdir)/bird.conf"
93
  CONTROL_SOCKET="$runtimedir/bird.ctl"
94
fi
95
AC_SUBST([CONFIG_FILE])
96
AC_SUBST([CONTROL_SOCKET])
97

    
98
AC_SEARCH_LIBS([clock_gettime], [rt posix4],
99
  [],
100
  [AC_MSG_ERROR([Function clock_gettime not available.])]
101
)
102

    
103
AC_CANONICAL_HOST
104

    
105
# Store this value because ac_test_CFLAGS is overwritten by AC_PROG_CC
106
if test "$ac_test_CFLAGS" != set ; then
107
  bird_cflags_default=yes
108
fi
109

    
110
AC_PROG_CC
111
AC_PROG_CC_C99
112
if test -z "$GCC" ; then
113
  AC_MSG_ERROR([This program requires the GNU C Compiler.])
114
fi
115

    
116
if test "$enable_pthreads" != no ; then
117
  BIRD_CHECK_PTHREADS
118

    
119
  if test "$bird_cv_lib_pthreads" = yes ; then
120
    AC_DEFINE([USE_PTHREADS], [1], [Define to 1 if pthreads are enabled])
121
    CFLAGS="$CFLAGS -pthread"
122
    LDFLAGS="$LDFLAGS -pthread"
123
    proto_bfd=bfd
124
  elif test "$enable_pthreads" = yes ; then
125
    AC_MSG_ERROR([POSIX threads not available.])
126
  fi
127

    
128
  if test "$enable_pthreads" = try ; then
129
    enable_pthreads="$bird_cv_lib_pthreads"
130
  fi
131
fi
132

    
133
if test "$bird_cflags_default" = yes ; then
134
  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign], [-Wall])
135
  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers], [-Wall -Wextra])
136
  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
137
  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
138

    
139
  CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wno-parentheses"
140
  BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign])
141
  BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers])
142
  BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
143
  BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
144
fi
145
AC_MSG_CHECKING([CFLAGS])
146
AC_MSG_RESULT([$CFLAGS])
147

    
148

    
149
AC_PROG_CPP
150
AC_PROG_INSTALL
151
AC_PROG_RANLIB
152
AC_CHECK_PROG([FLEX], [flex], [flex])
153
AC_CHECK_PROG([BISON], [bison], [bison])
154
AC_CHECK_PROGS([M4], [gm4 m4])
155

    
156
test -z "$FLEX"	 && AC_MSG_ERROR([Flex is missing.])
157
test -z "$BISON" && AC_MSG_ERROR([Bison is missing.])
158
test -z "$M4"	 && AC_MSG_ERROR([M4 is missing.])
159

    
160
BIRD_CHECK_PROG_FLAVOR_GNU([$M4],
161
  [],
162
  [AC_MSG_ERROR([Provided M4 is not GNU M4.])]
163
)
164

    
165
if test -n "$with_sysconfig" -a "$with_sysconfig" != no ; then
166
  if test -f $with_sysconfig ; then
167
    sysdesc=$with_sysconfig
168
  else
169
    sysdesc=$srcdir/sysdep/cf/$with_sysconfig
170
    if ! test -f $sysdesc ; then
171
      sysdesc=$sysdesc.h
172
    fi
173
  fi
174
elif test -f sysconfig.h ; then
175
  sysdesc=sysconfig
176
else
177
  case "$host_os" in
178
    linux*)
179
      sysdesc=linux
180
      default_iproutedir="/etc/iproute2"
181
      ;;
182
    freebsd*)
183
      sysdesc=bsd
184
      CPPFLAGS="$CPPFLAGS -I/usr/local/include"
185
      LDFLAGS="$LDFLAGS -L/usr/local/lib"
186
      ;;
187
    kfreebsd*)
188
      sysdesc=bsd
189
      ;;
190
    netbsd*)
191
      sysdesc=bsd
192
      CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
193
      LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
194
      ;;
195
    openbsd*)
196
      sysdesc=bsd
197
      ;;
198
    dragonfly*)
199
      sysdesc=bsd
200
      ;;
201
    *)
202
      AC_MSG_ERROR([Cannot determine correct system configuration. Please use --with-sysconfig to set it manually.])
203
      ;;
204
    esac
205
    sysdesc=$srcdir/sysdep/cf/$sysdesc.h
206
fi
207
AC_MSG_CHECKING([which OS configuration should we use])
208
AC_MSG_RESULT([$sysdesc])
209
if ! test -f $sysdesc ; then
210
  AC_MSG_ERROR([The system configuration file is missing.])
211
fi
212
sysname=`echo $sysdesc | sed 's/\.h$//'`
213
AC_DEFINE_UNQUOTED([SYSCONF_INCLUDE], ["$sysdesc"], [Which sysdep header to include])
214

    
215
AC_MSG_CHECKING([system-dependent directories])
216
sysdep_dirs="`sed <$sysdesc '/^Link: /!d;s/^Link: \(.*\)$/\1/' | tr '\012' ' '`"
217
AC_MSG_RESULT([$sysdep_dirs])
218
AC_SUBST([sysdep_dirs])
219

    
220
if test "$with_iproutedir" = no ; then with_iproutedir= ; fi
221

    
222
if test -n "$given_iproutedir"
223
then iproutedir=$with_iproutedir
224
else iproutedir=$default_iproutedir
225
fi
226

    
227
AC_SUBST([iproutedir])
228

    
229
DAEMON_LIBS=
230
AC_SUBST(DAEMON_LIBS)
231

    
232
if test "$enable_libssh" != no ; then
233
  AC_CHECK_HEADER([libssh/libssh.h], [true], [fail=yes], [ ])
234
  AC_CHECK_LIB([ssh], [ssh_connect], [true], [fail=yes])
235

    
236
  if test "$fail" != yes ; then
237
    AC_DEFINE([HAVE_LIBSSH], [1], [Define to 1 if you have the `ssh' library (-lssh).])
238
    DAEMON_LIBS="-lssh $DAEMON_LIBS"
239
    proto_rpki=rpki
240
    enable_libssh=yes
241
  else
242
    if test "$enable_libssh" = yes ; then
243
      AC_MSG_ERROR([LibSSH not available.])
244
    else
245
      enable_libssh=no
246
    fi
247
  fi
248
fi
249

    
250
if test "$enable_mpls_kernel" != no ; then
251
  BIRD_CHECK_MPLS_KERNEL
252

    
253
  if test "$bird_cv_mpls_kernel" = yes ; then
254
    AC_DEFINE([HAVE_MPLS_KERNEL], [1], [Define to 1 if kernel is MPLS capable])
255
  elif test "$enable_mpls_kernel" = yes ; then
256
    AC_MSG_ERROR([Kernel MPLS support not found.])
257
  fi
258

    
259
  if test "$enable_mpls_kernel" = try ; then
260
    enable_mpls_kernel="$bird_cv_mpls_kernel"
261
  fi
262
fi
263

    
264
all_protocols="$proto_bfd babel bgp ospf pipe radv rip $proto_rpki static"
265

    
266
all_protocols=`echo $all_protocols | sed 's/ /,/g'`
267

    
268
if test "$with_protocols" = all ; then
269
  with_protocols="$all_protocols"
270
fi
271

    
272
AH_TEMPLATE([CONFIG_BABEL], 	[Babel protocol])
273
AH_TEMPLATE([CONFIG_BFD],	[BFD protocol])
274
AH_TEMPLATE([CONFIG_BGP],	[BGP protocol])
275
AH_TEMPLATE([CONFIG_OSPF],	[OSPF protocol])
276
AH_TEMPLATE([CONFIG_PIPE],	[Pipe protocol])
277
AH_TEMPLATE([CONFIG_RADV],	[RAdv protocol])
278
AH_TEMPLATE([CONFIG_RIP],	[RIP protocol])
279
AH_TEMPLATE([CONFIG_RPKI],	[RPKI protocol])
280
AH_TEMPLATE([CONFIG_STATIC],	[Static protocol])
281

    
282
AC_MSG_CHECKING([protocols])
283
protocols=`echo "$with_protocols" | sed 's/,/ /g'`
284
if test "$protocols" = no ; then protocols= ; fi
285
for a in $protocols ; do
286
  if ! test -f $srcdir/proto/$a/Makefile ; then
287
    AC_MSG_RESULT([failed])
288
    AC_MSG_ERROR([Requested protocol $a not found])
289
  fi
290
  AC_DEFINE_UNQUOTED([CONFIG_`echo $a | tr 'a-z' 'A-Z'`])
291
done
292
AC_MSG_RESULT([ok])
293
AC_SUBST([protocols])
294

    
295
case $sysdesc in
296
  */linux*)
297
    AC_CHECK_HEADER([linux/rtnetlink.h],
298
      [],
299
      [AC_MSG_ERROR([Appropriate version of Linux kernel headers not found.])],
300
      [
301
	dnl Some older versions of Linux kernel headers require these includes
302
	#include <asm/types.h>
303
	#include <sys/socket.h>
304
      ]
305
    )
306
    ;;
307
esac
308

    
309
AC_CHECK_HEADERS_ONCE([alloca.h syslog.h])
310
AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [], [#include <sys/socket.h>])
311

    
312
AC_C_BIGENDIAN(
313
  [AC_DEFINE([CPU_BIG_ENDIAN], [1], [Define to 1 if cpu is big endian])],
314
  [AC_DEFINE([CPU_LITTLE_ENDIAN], [1], [Define to 1 if cpu is little endian])],
315
  [AC_MSG_ERROR([Cannot determine CPU endianity.])]
316
)
317

    
318
if test "$enable_debug" = yes ; then
319
  AC_DEFINE([DEBUGGING], [1], [Define to 1 if debugging is enabled])
320
  LDFLAGS="$LDFLAGS -rdynamic"
321
  CFLAGS="$CFLAGS -O0 -ggdb -g3 -gdwarf-4"
322

    
323
  AC_CHECK_HEADER([execinfo.h],
324
    [
325
      AC_DEFINE([HAVE_EXECINFO_H], [1], [Define to 1 if you have the <execinfo.h> header file.])
326
      AC_SEARCH_LIBS([backtrace], [execinfo],
327
	[],
328
	[AC_MSG_ERROR([Function backtrace not available.])]
329
      )
330
    ]
331
  )
332

    
333
  if test "$enable_memcheck" = yes ; then
334
    AC_CHECK_LIB([dmalloc], [dmalloc_debug])
335
    if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then
336
      AC_CHECK_LIB([efence], [malloc])
337
    fi
338
  fi
339
fi
340

    
341
CLIENT=birdcl
342
CLIENT_LIBS=
343
if test "$enable_client" = yes ; then
344
  CLIENT="$CLIENT birdc"
345
  BASE_LIBS="$LIBS"
346
  LIBS=""
347

    
348
  AC_CHECK_HEADERS([curses.h],
349
    [],
350
    [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
351
    [AC_INCLUDES_DEFAULT]
352
  )
353

    
354
  AC_SEARCH_LIBS([tgetent], [tinfo tinfow ncurses curses termcap],
355
    [TINFO_LIBS="$LIBS"; LIBS=""],
356
    [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
357
  )
358

    
359
  AC_CHECK_HEADERS([readline/readline.h readline/history.h],
360
    [],
361
    [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
362
    [AC_INCLUDES_DEFAULT]
363
  )
364

    
365
  AC_SEARCH_LIBS([rl_callback_read_char], [readline],
366
    [READLINE_LIBS="$LIBS"; LIBS=""],
367
    [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
368
    [$TINFO_LIBS]
369
  )
370

    
371
  AC_CHECK_LIB([readline], [rl_crlf],
372
    [AC_DEFINE([HAVE_RL_CRLF], [1], [Define to 1 if you have rl_crlf()])],
373
    [],
374
    [$TINFO_LIBS]
375
  )
376

    
377
  AC_CHECK_LIB([readline], [rl_ding],
378
    [AC_DEFINE([HAVE_RL_DING], [1], [Define to 1 if you have rl_ding()])],
379
    [],
380
    [$TINFO_LIBS]
381
  )
382

    
383
  LIBS="$BASE_LIBS"
384
  CLIENT_LIBS="$READLINE_LIBS $TINFO_LIBS"
385
fi
386
AC_SUBST([CLIENT])
387
AC_SUBST([CLIENT_LIBS])
388

    
389
mkdir -p $objdir/sysdep
390
AC_CONFIG_HEADERS([$objdir/sysdep/autoconf.h:sysdep/autoconf.h.in])
391
AC_CONFIG_FILES([Makefile:Makefile.in])
392
AC_OUTPUT
393

    
394
AC_MSG_RESULT()
395
AC_MSG_RESULT([BIRD was configured with the following options:])
396
AC_MSG_RESULT([        Source directory:	$srcdir])
397
AC_MSG_RESULT([        Object directory:	$objdir])
398
AC_MSG_RESULT([        Iproute2 directory:	$iproutedir])
399
AC_MSG_RESULT([        System configuration:	$sysdesc])
400
AC_MSG_RESULT([        Debugging:		$enable_debug])
401
AC_MSG_RESULT([        POSIX threads:		$enable_pthreads])
402
AC_MSG_RESULT([        Routing protocols:	$protocols])
403
AC_MSG_RESULT([        Kernel MPLS support:	$enable_mpls_kernel])
404
AC_MSG_RESULT([        Client:			$enable_client])
405

    
406
rm -f $objdir/.*-stamp